Debugging Ruby With Emacs

I’ve recently switched to using Emacs as my preferred IDE and really like its customizability. I started with Doom Emacs but eventually decided I wanted to understand the configurations better and switched to my own. However, I’m still keeping the Doom configurations around in case I run into issues with my configuration. I’m currently using chemacs to switch between the two profiles.

At work, I’m in a Ruby/Rails shop and wanted to improve my debugging experience in Emacs. Just as there are lsp and eglot for completions, there’s a nice package with equivalent abstractions for debugging called dape. It took me a while to figure out how to configure dape with my Rails project, so I wanted to share my configurations in case they’re helpful to others.

(defun my/merge-plists (&rest plists)
  (let ((rtn (copy-sequence (pop plists)))
        p v ls)
    (while plists
      (setq ls (pop plists))
      (while ls
        (setq p (pop ls) v (pop ls))
        (setq rtn (plist-put rtn p v))))
    rtn))

(defun my/dape-override-config (configs provider override)
  (let* ((provider-config (assoc provider configs))
         (config-plist (cdr provider-config)))
    (if provider-config
        (my/merge-plists config-plist override)
      (error "Provider %s not found in configs" provider))))

(defun my/setup-minitest-dape ()
  (let* ((config (my/dape-override-config
                  dape-configs
                  'rdbg
                  '(-c (format "RAILS_ENV=test bundle exec bin/rails test %s:%d"
                               (dape-buffer-default)
                               (line-number-at-pos))))))
    (cl-pushnew `(rdbg-test . ,config) dape-configs)))

;; have this somewhere that makes sense.
(eval-after-load 'dape #'my/setup-minitest-dape)

The extra code to override the dape configs is not strictly necessary but I’m keeping it in case I need to override the dape config for any other language.

Once you have this configured, you can run M-x dape with your cursor in a test block, select the rdbg-test configuration and start using the nicer UI for debuggging. Just ensure that you have the debug gem installed and have the starting breakpoint configured with require "debug"; binding.break.